Een UDF die een matrix retourneert:


Function lijstEvenOneven(bereik As Range, even As Boolean)
'even = 0 -> geeft lijst van even getallen
'even = 1 -> geeft lijst van oneven getallen
Dim lijst() As Single
Dim i As Integer, j As Integer, aantal As Integer, rest As Integer
  If bereik.Rows.Count > 1 And bereik.Columns.Count > 1 Then
    lijstEvenOneven = CVErr(xlErrRef)
    Exit Function
  End If
  rest = IIf(even, 1, 0)
  aantal = bereik.Cells.Count
  ReDim lijst(1 To aantal)
  j = 1
  For i = 1 To aantal
    If bereik(i) Mod 2 = rest Then
      lijst(j) = bereik(i)
      j = j + 1
    End If
  Next i
  If bereik.Columns.Count > 1 Then
    lijstEvenOneven = lijst
  Else
    lijstEvenOneven = Application.WorksheetFunction.Transpose(lijst)
  End If
End Function


kopieer de functie naar een module:
https://users.pandora.be/ingrid/excel/copyvba.htm#module

en voer deze in het werkblad als matrixformule in met [Ctrl][Shift]+[Enter],bijv.
=lijstEvenOneven(A1:A20;1)
om de oneven getallen uit het bereik A1:A20 weer te geven

Gebruik een aangepaste getalopmaak om de nullen te onderdrukken bijv.
Standaard;Standaard;;

Sterk.
Toch een vraagje omtrent Uw (prachtige) oplossing:
Waarom werkt deze wel als men bv. range B1:B20 selecteert en dan de formule =lijstEvenOneven(A1:A20;1) invult, maar niet indien men de formule in veld B1 invult en dan copieert naar B2:B20 ?
Thx

Sterk.
Toch een vraagje omtrent Uw (prachtige) oplossing:
Waarom werkt deze wel als men bv. range B1:B20 selecteert en dan de formule =lijstEvenOneven(A1:A20;1) invult, maar niet indien men de formule in veld B1 invult en dan copieert naar B2:B20 ?
Thx

Die functie moet als matrixformule ingevoerd worden. Het resultaat is een tabel, dat kan je dus niet in één cel invoeren maar moet je in een bereik plaatsen.